Menjalankan Visual Basic

I. Membuat Program Sederhana.

Visual Basic menyediakan beberapa template project yang didesain untuk mendukung pengembangan berbagai macam aplikasi dan komponen. Sebagai langkah utama untuk mengembangkan aplikasi, Anda harus menentukan tipe template project apa yang akan Anda gunakan. Template project berisi dasar objek project dan setting lingkungan yang Anda perlukan untuk membuat tipe aplikasi atau komponen yang akan dibangun.

A. Memulai menjalankan Visual Basic

1. Klik tombol Start, arahkan ke menu All Programs, kemudian submenu Microsoft Visual Studios 6.0, dan klik shortcut Microsoft Visual Basic 6.0.

2. Kotak dialog New Project akan ditampilkan. Pilih template project Standard EXE, kemudian klik tombol Open untuk

Memulai project baru Anda.
Project baru Anda akan diisi dengan sebuah form.

Lingkungan pemrograman Visual Basic akan ditampilkan seperti gambar di bawah ini

B. Menambah kontrol ke dalam form 1. Pilih salah satu kontrol dalam toolbox.

2. Klik dan tahan tombol mouse kiri samb il menyeret pointer ke posisi yang diinginkan dalam form. Kemudian, lepas tombol mouse.

3. Ulangi proses di atas untuk kontrol yang ingin Anda masukan dalam form.

C. Menjalankan aplikasi 1. Pada menu Run, klik Start atau tombol F5. Atau pada toolbar Visual Basic, klik Start.

Visual Basic akan membuka form sebagai program.

2. Coba klik kontrol yang telah Anda masukkan dalam form.

3.Tutup aplikasi yang berjalan dan kembali ke mode Design menggunakan salah satu cara berikut:
a. Pada Toolbar, klik tombol End.
b. Pada menu Run, klik End.
c. Pada menu system, klik Close.
d. Pada title bar, klik tombol Close.

D. Menset properti kontrol pada saat desain
1. Klik kontrol Label dalam form.

2. Dalam jendela Properties, ubah properti Caption menjadi Label Ku.

3. Pilih kontrol TextBox.

4. Dalam jendela Properties, set properti Text menjadi TextBoxKu.

D. Menset properti kontrol pada saat runtime
1. Klik ganda kontrol TextBox dalam form. Jendela Code Editor akan dibuka, menampilkan event procedure Text1_Change.

2. Tambahkan pernyataan berikut di dalam event prosedur Text1_Change:

Private Sub Text1_Change()
 Label1.Caption = Text1.Text
End Sub

Kode di atas akan mengubah judul kontrol Label dengan teks yang diketikkan dalam kontrol TextBox.

3.Jalankan aplikasi dan masukkan teks dalam text box. Lihat apa yang terjadi di kontrol Label.

4.Tutup aplikasi dengan menekan tombol Close pada title bar form dan lingkungan pemrograman Visual Basic muncul kembali.

E. Menyimpan project1. Dalam menu File, klik Save Project.

2. Ketika ditanyakan untuk menyimpan form, ubahlah lokasi folder ke c:\SES\Lat01, biarkan nama Form1.frm untuk disimpan, dan klik Save.

3. Ketika ditanyakan untuk menyimpan project, ubah lokasi folder ke c:\SES\Lat01, biarkan nama Project1 untuk disimpan, dan klik Save.

F. Membuat file .exe

1. Pada menu File, klik Make Project1.exe untuk membuat file executable. Yakinkan disimpan di folder c: \SES\Lat01.

2. Pada text box File name, ketikkan AplikasiKu kemudian klik OK. Visual Basic akan mengompilasi project dan membuat file executable yang dapat Anda jalankan langsung dari Windows.

G. Menjalankan file .exe

1. Klik tombol Start, arahkan ke All Programs, dan Accessories, kemudian klik Windows Explorer.

2. Dalam Windows Explorer, arahkan ke folder c:\SES\Lat01.

3.Jalankan aplikasi yang telah Anda buat dengan mengklik ganda pada file executable AplikasiKu.

4. Sebuah aplikasi Windows telah Anda jalankan tanpa melalui IDE Visual Basic Cobalah aplikasi dengan mengetik teks dalam text box.

5. Tutup aplikasi.

II. Memanipulasi Font

Program Font mensimulasikan pilihan huruf di mana Anda bisa memilih berbagai macam huruf dengan atributnya. Program ini akan menggunakan kontrol text box, combo box, label, frame, check box, dan command button. Kesemua objek tersebut dibuat ha nya dengan beberapa langkah singkat pada Visual Basic.

Ikuti langkah berikut untuk membuat program Font:

1. Jalankan Visual Basic lalu buka project Standard EXE baru.

Jika lingkungan pemrograman Visual Basic sudah berjalan, pada menu File, klik New Project untuk membuka project Standard EXE baru.

2. Tambahkan beberapa kontrol dan a tur lokasinya seperti gambar di bawah ini.

Catatan: Untuk membuat kontrol combo box seperti gambar Di atas, Anda harus menarik pada bagian bawah dari kontrol combo box.

3. Setting properti kontrol dengan nilai dalam tabel di bawah ini.

4. Ketikkan kode program di bawah ini pada Form1:

Private Sub Form_Load()
 Dim i As Integer
 
 ' Isi Combo1 dengan nama font
 For i = 0 To Screen.FontCount - 1
 Combo1.AddItem Screen.Fonts(i)
 Next
 
 ' Pilih daftar item pertama
 Combo1.ListIndex = 0
 ' Isi Combo2 dengan font style
 With Combo2
 . AddItem "Regular"
 .AddItem "Italic"
 .AddItem "Bold"
 .AddItem "Bold Italic"
 .ListIndex = 0
 End With
 
 ' Isi Combo2 dengan ukuran font
 For i = 8 To 24 Step 2
 Combo3.AddItem i
 Next
 
 Combo3.ListIndex = 0
 
End Sub
 
Private Sub Command1_Click()
 Unload Me
 
End Sub
 
Private Sub Command2_Click()
 
 Unload Me
End Sub
 ' Ubah nama font
Private Sub Combo1_Click()
Local_Change_Font
End Sub
 
Private Sub Combo2_Click()
 Local_Change_Font
End Sub
 
Private Sub Combo3_Click()
 Local_Change_Font
End Sub
 
' Rutin/Prosedur untuk merubah font
Private Sub Local_Change_Font()
 ' cek parameter size
 If Not IsNumeric(Combo3) Then
 Exit Sub
 End If
 
 ' Ubah font
 With Label4.Font
 .Name = Combo1 ' Nama font
 .Size = Val(Combo3) ' Ukuran font
 
 ' Attribut font
 Select Case Combo2
 Case "Regular"
 .Italic = False
 .Bold = False
 
 Case "Italic"
 .Italic = True
 .Bold = False
 
 Case "Bold"
 .Bold = True
 .Italic = False
 
 Case "Bold Italic"
 .Bold = True
 .Italic = True
 End Select
 End With
End Sub

5. Kini simpan project Anda di folder c:\SES\Font dan jalan-kan program Anda untuk melihat bagaimana cara kerja program Font. Klik tombol Start pada toolbar, atau dengan menekan tombol F5. Program dijalankan pada lingkungan pemrog-raman. Pilih nama, efek, dan ukuran font. Anda dapat melihat perubahan font pada kotak Sample.

6. Tutup form dengan menekan tombol Close pada title bar
untuk menghentikan program.

III. Membuat Kalender

Program yang akan kita buat kali ini akan menampilkan sebuah kalender dengan setting waktu dari sistem. Jika Anda berpikir membuat program ini akan sulit untuk pemula, jangan cemas; pasti mudah.

Ikuti langkah berikut untuk membuat program Kalender:

1. Jalankan Visual Basic lalu buka project Standard EXE baru. Jika lingkungan pemrograman Visual Basic sudah berjalan, pada menu File, klik New Project untuk membuka project Standard EXE baru.

2. Tambahkan kontrol Microsoft Windows Common Controls -26.0 (SP4) ke toolbox dengan salah satu cara berikut ini:
::Klik menu Project, lalu Component.
::Tekan kombinasi kontrol Ctrl+T.
::Kursor mouse diletakkan di toolbox kemudia n klik-kanan, lalu pada menu pop-up yang muncul, klik Components.

3. Pada kotak dialog Components, klik nama kontrol Microsoft Windows Common Controls-2 6.0 (SP4). Klik OK, untuk memilih kontrol.

Ketika Anda menambah kontrol ActiveX dari kotak dialog Components, kontrol tersebut akan langsung ditampilkan dalam jendela toolbox.

4. Pilih kontrol MonthView dari jendela toolbox. Klik ganda kontrol MonthView untuk menambah kontrol ke Form1.

5. Kini simpan project Anda di folder c:\SES\Kalender dan jalankan program Anda untuk melihat bagaimana cara kerja program Font. Klik tombol Start pada toolbar, atau dengan menekan tombol F5. Program dijalankan pada lingkungan pemrograman dan menampilkan informasi waktu dari sistem.

6. Tutup form dengan menekan tombol Close pada title bar untuk menghentikan program.

IV. Menggunakan Kotak Pesan

Salah satu fungsi kotak pesan yang berguna menampilkan output adalah fungsi MsgBox. Fungsi MsgBox mengambil satu atau lebih argumen sebagai inputnya, lalu hasil fungsi tersebut bisa diberikan ke variabel.

1. Jalankan Visual Basic lalu buka project Standard EXE baru. Jika lingkungan pemrograman Visual Basic sudah berjalan, pada menu File, klik New Project untuk membuka project Standard EXE baru.

2. Tambahkan beberapa kontrol dan atur lokasinya seperti gambar di bawah ini .

3. Setting properti kontrol dengan nilai dalam tabel di bawah ini.>

4. Ketikkan kode program di bawah ini pada Form1:

Private Sub Form_Load()
 
 'Pilihan style tombol
 With Combo1
 .AddItem "0 - vbOKOnly"
 .AddItem "1 - vbOKCancel"
 .AddItem "2 - vbAbortRetryIgnore"
 .AddItem "3 - vbYesNoCancel"
 .AddItem "4 - vbYesNo"
 .AddItem "5 - vbRetryCancel"
 .ListIndex = 0
 End With
 
 'Pilihan icon
 With Combo2
 .AddItem "16 - vbCritical"
 .AddItem "32 - vbQuestion"
 .AddItem "48 - vbExclamation"
 .AddItem "64 - vbInformation"
 .ListIndex = 3
 End With
 
 'Pilihan default tombol
 With Combo3
 .AddItem "0 - vbDefaultButton1"
 .AddItem "256 - vbDefaultButton2"
 .AddItem "512 - vbDefaultButton3"
 .AddItem "768 - vbDefaultButton4"
 .ListIndex = 0
 End With
End Sub
 
Private Sub Command1_Click()
 
 'var untuk argumen MsgBox
 Dim nButton As Integer
 Dim nResult As Integer
 Dim sName As String
 
 nButton = Val(Combo1) + Val(Combo2) + _
 Val(Combo3)
 'tampilkan msgbox
 nResult = MsgBox(Text1, nButton, Text2)
 
 'Tampilkan tombol yg dipilih
 sName = Choose(nResult, "OK", _
 "Cancel", "Abort", "Retry", _
 "Ignore", "Yes", "No")
 
 MsgBox "Tombol yang ditekan: " & sName
 
End Sub
 
' rutin di bawah ini untuk meng-update
' sintaks dalam Text3
Private Sub Combo1_Click()
 Show_Sintax
End Sub
 
Private Sub Combo2_Click()
 Show_Sintax
End Sub
 
Private Sub Combo3_Click()
 Show_Sintax
End Sub
 
Private Sub Text1_Change()
 Show_Sintax
End Sub
 
Private Sub Text2_Change()
 Show_Sintax
End Sub
 
Private Sub Show_Sintax()
 'Tampilkan sintaks MsgBox di Text3
 Dim nButton As Integer
 nButton = Val(Combo1) + _
 Val(Combo2) + _
 Val(Combo3)
 
 Text3 = "MsgBox( """ & Text1 & _
 """, " & nButton & ", """ & _
 Text2 & """ )"
 
End Sub

5. Kini simpan project Anda di folder c:\SES\KotakPesan dan jalankan program Anda untuk melihat bagaimana cara kerja program. Klik tombol Start pada toolbar, atau dengan menekan tombol F5.

Program dijalankan pada lingkungan pemrograman. Ketikkan pesan dan judul pada kotak teks, pilih beberapa opsi untuk fungsi MsgBox, dan klik tombol Tampilkan MsgBox. Gambar berikut menampilkan simulasi pembuatan kotak dialog MsgBox.

6. Tutup form dengan menekan tombol Close pada title bar untuk menghentikan program.

V. Menggunakan Variabel

Program Variabel mendemonstrasikan cara menggunakan variabel untuk menyimpan data secara sementara pada program dan bagaimana menggunakan operator matematik untuk melakukan tugas-tugas seperti penjumlahan dan perkalian.

Ikuti langkah berikut untuk membuat program variabel:

1. Jalankan Visual Basic lalu buka project Standard EXE baru. Jika lingkungan pemrograman Visual Basic sudah berjal an, pada menu File, klik New Project untuk membuka project Standard EXE baru.

2.Tambahkan beberapa kontrol dan atur lokasinya seperti gambar di bawah ini .

3. Setting properti kontrol dengan nilai dalam tabel di bawah ini.

4. Ketikkan kode program di bawah ini pada Form1:

Option Explicit
 
Private Const MY_STRING = "The quick" & _
 " brown fox jumps" & _
 "over the lazy dog."
 
Private Sub Form_Load()
 
 'Isi combo1 untuk operator matematika
 With Combo1
 .AddItem "Penjumlahan (+)"
 .AddItem "Pengurangan (-)"
 .AddItem "Perkalian (*)"
 .AddItem "Pembagian (/)"
 .ListIndex = 0
 End With
 
 'Isi Text4 dengan konstanta MY_STRING
 Text4 = MY_STRING
 'Isi Combo2 dengan fungsi string
 With Combo2
 .AddItem "Left(text, 3)"
 .AddItem "Right(text, 4)"
 .AddItem "Mid(text, 5, 24)"
 .AddItem "Ucase(text)"
 .AddItem "Lcase(text)"
 .AddItem "StrConv(text, vbProperCase)"
 .ListIndex = 0
 
 End With
End Sub
 
Private Sub Command1_Click()
 Dim Var1 As Variant
 Dim Var2 As Variant
 Dim nResult As Double
 
 'Simpan dan konversi ke tipe numerik
 Var1 = Val(Text1)
 Var2 = Val(Text2)
 
 'Hitung
 Select Case Combo1.ListIndex
 Case 0
 'Penjumlahan
 nResult = Var1 + Var2
 
 Case 1
 'Pengurangan
 nResult = Var1 - Var2
 
 Case 2
 'Perkalian
 nResult = Var1 * Var2
 
 Case 3
 'Pembagian
 nResult = Var1 / Var2
 
 End Select
 
 'Tampilkan hasil di Text3
 Text3 = nResult
 
End Sub
 
Private Sub Command2_Click()
 Dim text As String
 Dim sResult As String
 
 'Isikan var text dengan Text4
 text = Text4
 
 Select Case Combo2.ListIndex
 Case 0
 sResult = Left(text, 3)
 
 Case 1
 sResult = Right(text, 4)
 Case 2
 sResult = Mid(text, 5, 24)
 Case 3
 sResult = UCase(text)
 Case 4
 sResult = LCase(text)
 Case 5
 sResult = StrConv(text, _
 vbProperCase)
 End Select
 
 'Tampilkan dalam Text5
 Text5 = sResult
 
End Sub

5. Kini simpan project Anda di folder c:\SES\Variabel dan jalankan program Anda untuk melihat bagaimana cara kerja program. Klik tombol Start pada toolbar, atau dengan menekan tombol F5.

Program dijalankan pada lingkungan pemrograman. Masukan angka dalam variablel 1 dan variabel 2, klik tombol Hitung. Berikut ini gambar dari program variabel.

6. Tutup form dengan menekan tombol Close pada title bar untuk menghentikan program.

VI. Menggunakan Multimedia

Kontrol Windows Media Player terdapat dalam file Windows Media Player (wmp.dll). Untuk menggunakan kontrol ini pada program, Anda harus menambah kontrol ke dalam toolbox dengan perintah Com-ponents (Ctrl+T) pada menu Project, lalu mengklik kontrol dan membuat antarmuka baris perintah untuk tool pada form Anda.

Ikuti langkah berikut untuk membuat program multimedia:

1. Jalankan Visual Basic lalu buka project Standard EXE baru.

Jika lingkungan pemrograman Visual Basic sudah berjalan, pada menu File, klik New Project untuk membuka project Standard EXE baru.

2. Klik perintah Components (Ctrl+T) pada menu Project. Tandai kontrol Microsoft Common Dialog Control 6.0 dan Windows Media Player seperti gambar di bawah ini.

3. Klik OK pada kotak dialog Components. Tambahkan beberapa kontrol dan atur lokasinya seperti gambar di bawah ini.

Setting properti kontrol dengan nilai dalam tabel di bawah ini.

4. Ketikkan kode program di bawah ini pada Form1:

Option Explicit
 
Private Sub Form_Load()
 
 ' Ubah setting media player
 WindowsMediaPlayer1. _
 settings.autoStart = False
 
End Sub
 
Private Sub Command1_Click()
 Dim sFile As String
 
 'Tampilkan kotak dialog Open
 With CommonDialog1
 .Filter = "All Files|*.*|Wave|" & _
 "*.wav|MPx Files|*.mp3"
 .FilterIndex = 3
 .DefaultExt = "mp3"
 .DialogTitle = _
 "Menambah file multimedia"
 .CancelError = False
 .ShowOpen
 sFile = .FileName
 
 'Tambahkan file
 If Len(sFile) <> 0 Then
 List1.AddItem sFile
 End If
 
 End With
 
End Sub
Private Sub Command2_Click()
 If List1.ListIndex <> -1 Then
 'Hapus item dalam list
 List1.RemoveItem List1.ListIndex
<bt/>
 End If
End Sub
 
Private Sub Command3_Click()
 'Hapus semua list
 List1.Clear
End Sub
 
Private Sub List1_Click()
 If Len(WindowsMediaPlayer1.URL) = 0 Then
 'Buka file multimedia
 WindowsMediaPlayer1.URL = List1
 End If
End Sub
 
Private Sub List1_DblClick()
 Dim sFile As String
 sFile = List1
 If Len(sFile) <> 0 Then
 'Jalankan file multimedia
 With WindowsMediaPlayer1
 .URL = sFile
 .Controls.play
 End With
 Caption = Dir(sFile)
 End If
End Sub

5. Kini simpan project Anda di folder c:\SES\Multimedia dan jalankan program Anda untuk melihat bagaimana cara kerja program. Klik tombol Start pada toolbar, atau dengan menekan tombol F5.

A. Buka project dalam folder c:\SES\Font.

Setting properti kontrol dengan nilai dalam tabel di bawah ini.

Tambahkan kode dalam prosedur Local_Change_Font untuk mengubah effect font ketika user mengklik kontrol CheckBox. Contohnya seperti gambar berikut ini.

Gunakan properti Strikeout dan Underline milik objek Font untuk mengubah efek font.

B. Buka project dalam folder c:\SES\Kalender.

Tambahkan fitur untuk menampilkan jam digital dalam program kalender. Untuk menampilkan jam digital, Anda perlu kontrol Timer untuk mengambil informasi waktu dan kontrol Label untuk menampilkannya. Contohnya seperti gambar di bawah ini.

Set properti Interval milik kontrol Timer menjadi 500. Tambahkan kode untuk menampilkan jam dalam event Timer1_Timer() milik kontrol Timer. Contoh program sepert i gambar di bawah ini.

C. Buka project dalam folder c:\SES\KotakPesan.

Tambahkan fungsi InputBox untuk menampilkan sebuah kotak dialog pada layar lalu menyimpan teks yang diketikkan oleh pengguna ke dalam variabel. Fungsi ini sangat berguna untuk berinteraksi langsung dengan pengguna. Berikut contoh gambar yang dihasilkan oleh fungsi InputBox.

Sintaks fungsi InputBox adalah sebagai berikut:

sVar = InputBox ( prompt [,title] [,xpos]
[,ypos]
<br. [,helpfile, context] )

Di mana prompt adalah teks yang akan ditampilkan pada layar, title adalah adalah teks yang ditampilkan pada baris judul kotak pesan, xpos dan ypos adalah posisi kiri atas dan kanan atas kotak dialog, dan helpfile dan context adalah file dan id untuk menampilkan jendela pertolongan.

Tambahkan sebuah kontrol CommandButton untuk memanggil fungsi InputBox seperti gambar berikut .

Untuk argumen fungsi InputBox, Anda dapat menggunakan teks dalam kontrol Text1 dan Text2 dalam form. Contoh hasil akhir soal ini seperti gambar berikut .

Tampilkan juga hasil fungsi InputBox dalam kotak pesan MsgBox seperti gambar berikut ini .

D. Buka project dalam folder c:\SES\Variabel.

Tambahkan dua buah fungsi berikut ini dalam kotak input Fungsi string.

::Len. Fungsi ini digunakan untuk menghitung jumlah karakter dalam string yang disimpan dalam variabel atau properti.
::InStr. Fungsi ini mengembalikan angka yang menun-jukkan posisi string berada.
Berikut gambar dari program variabel yang sudah ditam-bahkan fungsi baru.

Masih dalam program Variabel, tambahkan fungsi matematika berikut ini:
::Abs. Fungsi ini mengembalikan nilai absolut dari nilai yang dimasukkan.
::Mod. Fungsi ini digunakan untuk membagi dua angka dan mengembalikan nilai sisa dari hasil pembagian tersebut.

Berikut gambar dari program variabel yang sudah ditambahkan fungsi baru.

E. Buka project dalam folder c:\SES\Multimedia.

Tambahkan fitur untuk menyimpan daftar lagu ke dalam registry. Visual Basic menyediakan fungsi SaveSetting (menyimpan informasi dalam registry) dan GetAllSettings (mengambil informasi dalam registry) untuk memanipulasi data dalam
registry.

Gunakan fungsi GetAllSettings ketika program pertama kali dijalankan dan fungsi SaveSetting ketika program ditutup. Berikut contoh kode untuk mengambil informasi dari registry:

'Ambil playlist dari registry
 Dim reg As Variant, i As Integer
 reg = GetAllSettings("MyMultimedia", _"Playlist")
<bt/>
 If Not IsEmpty(reg) Then
 ReDim aPlayList(UBound(reg))
 
 For i = LBound(reg, 1) To _UBound(reg, 1)
 
 'Tambahkan ke List1
 List1.AddItem reg(i, 1)
 Next
<br/.
End If

Dan untuk menyimpan, Anda dapat menggunakan contoh kode berikut:

'Tambahkan ke registry
 Dim i As Integer
 
 For i = 0 To List1.ListCount 1
 
 SaveSetting "MyMultimedia", _
 "PlayList", "File" & i, _
 List1.List(i)
 Next

Tambahkan juga fasilitas untuk membuka file movie seperti tipe file AVI, MPEG, atau DAT. Contohnya seperti gambar di baw ah ini.

Salam...
By. KOKODA

:K::O::K::O::D::A::TIPS::INTERNET:

Rabu, 01 Juli 2009

Menjalankan Visual Basic

Artikel yang berkaitan

0 komentar:

Posting Komentar

Google Translate My Site

pesan

Tips Internet